早稲田大学プログラミングコンテスト2019: F - RPG

https://atcoder.jp/contests/wupc2019/tasks/wupc2019_f

問題概要

N頂点M辺の有向無閉路グラフが与えられる。グラフの各頂点は必ず「戦闘」もしくは「空き地」のいずれかに分類される。また空き地の頂点iには整数のコストCiを支払うことで回復所を設置することができる。頂点1から頂点Nまで移動するとき、どのような経路を通ったとしても2つの戦闘頂点間を移動する間には必ずひとつ以上の回復所を通過するように回復所を設置したい。設置に必要なコスト合計の最小値を求めよ。

N <= 500

M <= 1000

解法

フローをやる。辺の張り方はいろいろあると思うが、自分は次のようにやった。

  • 頂点を倍加して各頂点に「入頂点」「出頂点」をつくる
  • 戦闘頂点ではsourceから出頂点へ、入頂点からsinkへそれぞれ容量INFで辺を張る
  • 空き地頂点では自分の入頂点から自分の出頂点に対して容量Ciで辺を張る
  • あとは与えられたグラフどおりに容量INFで出頂点から入頂点への辺を張っていく

あとはこのグラフにフローを流して最大流を求めれば答えが出る。この問題で求められているような回復所の設置の仕方はすべての戦闘頂点の出頂点がsource側、入頂点がsink側になるようグラフをカットするものと捉えることができて、INFの辺は実質カットできないものと見なすとあとは空き地頂点の容量Ciの辺を切る(=そこに回復所を設置する)しかないので、結果最小カット(=最大流)が答えとなる、という感じ(たぶん)

感想

カットで頂点をsource側sink側の2種類に分けるという考え方重要っぽい フローよくわかってないのでなんか変なこと言ってたら教えてください

こいつ最近F問題の記事ばっか書いてるな

コード (D言語)

import std.stdio, std.array, std.string, std.conv, std.algorithm;
import std.typecons, std.range, std.random, std.math, std.container;
import std.numeric, std.bigint, core.bitop;
 
immutable long MOD = 10^^9 + 7;
immutable long INF = 10L^^15;

void main() {
    auto s = readln.split.map!(to!int);
    auto N = s[0];
    auto M = s[1];
    auto C = 0 ~ readln.split.map!(to!(long)).array ~ 0;
    auto G = new int[][](N);
    foreach (i; 0..M) {
        s = readln.split.map!(to!int);
        G[s[0]-1] ~= s[1]-1;
    }
    
    int source = 0;
    int sink = N - 1;
    auto ff = new FordFulkerson!long(N*2, source, sink);

    foreach (i; 1..N-1) {
        if (C[i] == -1) {
            ff.add_edge(source, i, INF);
            ff.add_edge(i+N, sink, INF);
        } else {
            ff.add_edge(i+N, i, C[i]);
        }

        foreach (j; G[i]) {
            ff.add_edge(i, j+N, INF);
        }
    }

    long ans = ff.run;
    writeln( ans < INF ? ans : -1 );
}

class FordFulkerson(T) {
    int N, source, sink;
    int[][] adj;
    T[][] flow;
    bool[] used;

    this(int n, int s, int t) {
        N = n;
        source = s;
        sink = t;
        assert (s >= 0 && s < N && t >= 0 && t < N);
        adj = new int[][](N);
        flow = new T[][](N, N);
        used = new bool[](N);
    }

    void add_edge(int from, int to, T cap) {
        adj[from] ~= to;
        adj[to] ~= from;
        flow[from][to] = cap;
    }

    T dfs(int v, T min_cap) {
        if (v == sink)
            return min_cap;
        if (used[v])
            return 0;
        used[v] = true;
        foreach (to; adj[v]) {
            if (!used[to] && flow[v][to] > 0) {
                auto bottleneck = dfs(to, min(min_cap, flow[v][to]));
                if (bottleneck == 0) continue;
                flow[v][to] -= bottleneck;
                flow[to][v] += bottleneck;
                return bottleneck;
            }
        }
        return 0;
    }

    T run() {
        T ret = 0;
        while (true) {
            foreach (i; 0..N) used[i] = false;
            T f = dfs(source, T.max);
            if (f > 0)
                ret += f;
            else
                return ret;
        }
    }
}