全国統一プログラミング王決定戦予選 / NIKKEI Programming Contest 2019: E - Weights on Vertices and Edges

https://atcoder.jp/contests/nikkei2019-qual/tasks/nikkei2019_qual_e

問題概要

N頂点M辺の連結な無向グラフが与えられる。グラフの各頂点と各辺には重みが設定されている。辺をひとつ選んでグラフから削除するという操作を何回でも行えるとき、削除されていないすべての辺について、その辺の重みがその辺の属する連結成分の全頂点の重みの総和を超えないという条件が満たされた状態するために最小何本の辺を削除する必要があるか求めよ。

N, M <= 105

解法

明らかに重い辺ほど削除対象になりやすいことを考えると、以下のようなステップで問題を解くことができる。

  1. まだ削除もマークもされていない中で最大の重みを持つ辺を見る。
  2. その辺が条件を満たしていないならば、削除する。
  3. その辺が条件を満たしているならば、その辺が属する連結成分のすべての辺は必ず条件を満たす。なのでそのような辺をすべて残存確定としてマークする。
  4. 削除もマークもされていない辺がなくなるまで1に戻ってこれを繰り返す。

これをそのまま実装しようとすると、辺の削除とそれに伴う連結成分の分割が必要になるが、そのような操作は基本的に難しい。なのでこの類の操作を要求される問題でよく用いられるテクニックである「操作を逆順で考える」をやる。つまりはじめは辺が全部削除された状態で頂点だけがあり、だんだん辺が追加されていく、というような形である。辺を追加して連結成分をくっつけていく操作はUnionFindのようなデータ構造で簡単に行えるため、こちらの方が操作もしやすく見通しがよい。

上の操作を逆順にやる場合、軽い辺から順に繋いでいくことになるが、上に書いたことをそのままやることは難しい。特にステップ3の他の辺を残存確定とするところが邪魔で、これを逆操作で再現するのはどうにも無理っぽい感じがする(逆から見ていく以上、その辺が残存確定になっているかどうかは知りようがないため)。なので逆操作をしやすくするために、上の操作を少し言い換える。具体的には毎ステップ必ず削除を行うようにして、逆操作における追加操作と対応がつくようにする。手順としては以下のようになる。

  1. まだ見ていない中で最大の重みの辺を見る。
  2. その辺が条件を満たしているならば、その辺が属する連結成分のすべて辺は必ず条件を満たす。なのでそのような辺をすべてマークする。
  3. その辺を 必ず 削除する。ただしその辺がマークされている場合、最終的な答えの削除数にはカウントしない。
  4. すべての辺を見るまでこれを繰り返す。

このようにすると毎回辺の削除が行われるので逆操作との対応がつきやすくなる。これに基づいた逆操作は以下のようになる。

  1. まだ見ていない中で最小の重みの辺を見る。
  2. その辺を繋げる。つまり辺が頂点(u, v)間を繋ぐとき、uの属する連結成分とvの属する連結成分をひとつの連結成分にまとめる。この操作は元の操作における削除に対応しているため、コストに+1を加算する。
  3. 辺の重みがこれによってできた連結成分内の全頂点の重みの総和未満である場合、この時点でこの連結成分に属している辺はすべて条件を満たす。よってそれらすべての辺の削除はなかったことにできるので、それらすべての辺によって足されたコストを無効にする。
  4. すべての辺を見るまでこれを繰り返す。

実装上ではUnionFindの各連結成分にコストを持たせておくと管理しやすい(uniteするときはコストを足す、無効にするときはゼロにする、というようにすると最終的にひとつの連結成分になったときのコストが答えになる)。

感想

アルメリアさんのツイートを見て解けました

解法はなんかどう書いても天下り的な感じになってしまってむずかしい おもいつきたいね

コード (D言語)

import std.stdio, std.array, std.string, std.conv, std.algorithm;
import std.typecons, std.range, std.random, std.math, std.container;
import std.numeric, std.bigint, core.bitop, core.stdc.string;

void main() {
    auto s = readln.split.map!(to!int);
    auto N = s[0];
    auto M = s[1];
    auto X = readln.split.map!(to!long).array;
    auto G = new Tuple!(int, long)[][](N);
    auto E = new Tuple!(int, int, long)[](M);
    foreach (i; 0..M) {
        s = readln.split.map!(to!int);
        G[s[0]-1] ~= tuple(s[1]-1, s[2].to!long);
        G[s[1]-1] ~= tuple(s[0]-1, s[2].to!long);
        E[i] = tuple(s[0]-1, s[1]-1, s[2].to!long);
    }

    E.sort!"a[2] < b[2]";
    auto uf = new UnionFind(N, X);

    foreach (e; E) {
        uf.unite(e[0], e[1]);
        int u = uf.find(e[0]);
        if (uf.weights[u] >= e[2]) {
            uf.unused_edges[u] = 0;
        }
    }

    int u = uf.find(0);
    uf.unused_edges[u].writeln;
}



class UnionFind {
    int N;
    int[] table;
    long[] weights;
    long[] unused_edges;

    this(int n, long[] X) {
        N = n;
        table = new int[](N);
        fill(table, -1);
        weights = new long[](N);
        foreach (i; 0..N) weights[i] = X[i];
        unused_edges = new long[](N);
    }

    int find(int x) {
        return table[x] < 0 ? x : (table[x] = find(table[x]));
    }

    void unite(int x, int y) {
        x = find(x);
        y = find(y);
        if (table[x] > table[y]) swap(x, y);
        unused_edges[x] += 1;
        if (x == y) return;
        weights[x] += weights[y];
        unused_edges[x] += unused_edges[y];
        table[x] += table[y];
        table[y] = x;
    }
}