yukicoder No.614 壊れたキャンパス

問題概要

K階建ての棟がN個あり、棟a_iのある階と棟(a_i+1)のある階を結ぶ渡り廊下がM個ある。「コスト0で渡り廊下を渡る」「コスト1で同じ棟の1つ上または1つ下の階に移動する」の2種類の移動が行えるとき、棟1のS階から棟NのT階へ移動するために必要なコストの最小値を求めよ。

N <= 2×10⁵, M <= 2×10⁵, K <= 10⁹

解法

頂点と辺をうまいこと張ってダイクストラをする。

頂点は（棟, 階）のペアとする。ここで頂点として考える必要があるのは各渡り廊下の両端と(1, S)と(N, T)のみである。渡り廊下の両端は高々2M個なので、頂点数はO(M)で抑えられる。

次に辺を張る。まず渡り廊下に関しては定義通りに普通に辺を張ればよい。問題になるのが同じ棟内での移動で、ここを愚直にやろうとすると辺の数がO(M²)になってしまうが、実はそんなことをする必要はなく、各頂点から見て同じ棟の上下でそれぞれ一番近い階だけに辺を張ればよい（それより遠くに行く場合でもそこは絶対通るので）。これで辺の数もO(M)になる。ダイクストラを回すとO(MlogM)。

感想

1ヶ月くらい競プロ的に死んでたのでぼちぼち元に戻していきたい

コード

import std.stdio, std.array, std.string, std.conv, std.algorithm;
import std.typecons, std.range, std.random, std.math, std.container;
import std.numeric, std.bigint, core.bitop;

immutable long INF = 1L << 60;
alias Edge = Tuple!(int, "bld", int, "floor");

void main() {
    auto s = readln.split.map!(to!int);
    auto N = s[0];
    auto M = s[1];
    auto K = s[2];
    auto S = s[3];
    auto T = s[4];
    auto G = new Edge[][int][](N);
    auto floors = new int[][](N);
    foreach (_; 0..M) {
        s = readln.split.map!(to!int);
        G[s[0]-1][s[1]] ~= Edge(s[0], s[2]);
        floors[s[0]-1] ~= s[1];
        floors[s[0]] ~= s[2];
    }
    floors[0] ~= S;
    floors[N-1] ~= T;

    foreach (i; 0..N) {
        floors[i].sort();
        foreach (j; 0..floors[i].length.to!int-1) {
            G[i][floors[i][j]] ~= Edge(i, floors[i][j+1]);
            G[i][floors[i][j+1]] ~= Edge(i, floors[i][j]);
        }
    }


    auto dist = new long[int][](N);
    foreach (i; 0..N)
        foreach (j; floors[i])
            dist[i][j] = INF;
    
    auto pq = new BinaryHeap!(Array!(Tuple!(int, int, long)), "a[2] > b[2]");
    pq.insert(tuple(0, S, 0L));

    while (!pq.empty) {
        auto tt = pq.front;
        pq.removeFront;
        auto b = tt[0];
        auto f = tt[1];
        auto cost = tt[2];
        if (dist[b][f] <= cost) continue;
        dist[b][f] = cost;
        if (!(f in G[b])) continue;
        
        foreach (e; G[b][f]) {
            auto nb = e.bld;
            auto nf = e.floor;
            auto nc = cost + (b == nb ? abs(f-nf) : 0L);
            if (nc < dist[nb][nf]) pq.insert(tuple(nb, nf, nc));
        }
    }

    if (dist[N-1][T] >= INF) dist[N-1][T] = -1;
    dist[N-1][T].writeln; 
}