問題概要

N個の中継局が二次元平面上の相異なる整数座標上に存在する。中継局と中継局は距離10以下であれば通信でき、無線機と中継局、無線機と無線機は距離1以下であれば通信できる。加えて、同じ中継局と通信できるもの同士も通信することができる。2次元平面上の任意の位置に2つの無線機を通信できるように置くとき、2つの無線機の間の距離の最大値を求めよ。

N <= 120000

-10000 <= Xi, Yi <= 10000

解法

手順1. 通信できる中継局を1つのグループにまとめる
手順2. 各グループの中で最遠点対を求める

まず手順1では距離が10以下という条件を満たす中継局同士をUnionFind等でまとめていく。ただし単純にすべての組の距離を求めているとO(N²)で間に合わない。ここで見るべき距離が10以下と小さいことを生かすと、ひとつの中継局においてはx, yが高々-10～10の正方形の範囲に存在する中継局との距離だけを調べれば十分であることがわかる。これは各中継局をx座標ごとにバケット分けした上で各バケットをy座標でソートしたりしておけば、二分探索でO(NlogN)でできる（具体的には(x-10)～(x+10)のバケットそれぞれにおいて、二分探索で(y-10)以上の最初の点を見つけて、y+10を超えるまで順に距離を確かめるという手順をとればよい。中継局は整数座標かつ相異なるという条件が効いているので、実際に距離を確かめる回数はひとつの中継局につき最大でも20×20回程度に抑えられる）。

手順2では手順1で求めたグループごとに最遠点対を割り出し、その最大距離を求める。やり方としては各グループで凸包を作ってその中の点対を総当たりすればよい。x, yの取りうる範囲が狭いこと、整数座標しかありえないことから凸包はそんなに大きくならず、凸包内で二乗の総当たりをしても十分間に合う。最後に無線機2台分の距離2を足せば答え。

感想

条件となる距離が小さいならば近くをちょっとだけ調べればいい、最遠点対は凸包上にある、整数座標という制限があると凸包もそんなに自由な形はとれない、といった学びがあった

コード (D言語)

import std.stdio, std.array, std.string, std.conv, std.algorithm;
import std.typecons, std.range, std.random, std.math, std.container;
import std.numeric, std.bigint, core.bitop;

void main() {
    auto N = readln.chomp.to!int;
    auto P = N.iota.map!(_ => readln.split.map!(to!int)).map!(a => Point(a[0], a[1])).array;

    if (N == 0) {
        writeln(1);
        return;
    }

    Tuple!(int, int)[][int] X;
    foreach (i, p; P.enumerate) {
        X[p.x] ~= tuple(p.y, i.to!int);
    }
    foreach (k; X.keys) X[k].sort();

    auto uf = new UnionFind(N);
    foreach (i, p; P.enumerate) {
        foreach (dx; -10..11) {
            int nx = p.x + dx;
            if (nx !in X) continue;
            int j = X[nx].assumeSorted.lowerBound(tuple(p.y, 0)).length.to!int;
            for (int k = j; k < X[nx].length; ++k) {
                int ny = X[nx][k][0];
                if (dx * dx + (ny - p.y) * (ny - p.y) > 100) break;
                if (nx != p.x || ny != p.y) uf.unite(i.to!int, X[nx][k][1]);
            }
            for (int k = min(j, X[nx].length.to!int-1); k >= 0; --k) {
                int ny = X[nx][k][0];
                if (dx * dx + (ny - p.y) * (ny - p.y) > 100) break;
                if (nx != p.x || ny != p.y) uf.unite(i.to!int, X[nx][k][1]);            
            }
        }
    }

    int farest = 0;
    foreach (i; 0..N) {
        if (uf.groups[i].empty) continue;
        auto ch = convex_hull(uf.groups[i].map!(i => P[i]).array);
        foreach (j; 0..ch.length) {
            foreach (k; j+1..ch.length) {
                farest = max(farest, dist2(ch[j], ch[k]));
            }
        }
    }

    writefln("%.9f", sqrt(farest * 1.0L) + 2);
}

struct Point {
    int x;
    int y;
}

Point[] convex_hull(Point[] points) {
    int N = points.length.to!int;
    points.sort!((a, b) => a.x == b.x ? a.y < b.y : a.x < b.x);
    Point[] ch1, ch2;
    foreach (i; 0..N) {
        while (ch1.length >= 2 && rot(ch1[$-2], ch1[$-1], points[i]) <= 0) ch1.popBack;
        ch1 ~= points[i];
    }
    foreach_reverse (i; 0..N) {
        while (ch2.length >= 2 && rot(ch2[$-2], ch2[$-1], points[i]) <= 0) ch2.popBack;
        ch2 ~= points[i];
    }

    auto ch = ch1 ~ ch2;
    return ch.sort!((a, b) => a.x == b.x ? a.y < b.y : a.x < b.x).uniq.array;
}

int rot(Point a, Point b, Point c) {
    // a -> b -> c の向き
    // 正なら左、負なら右、0なら同一直線状
    return (b.x - a.x) * (c.y - a.y) - (b.y - a.y) * (c.x - a.x);
}

int dist2(Point a, Point b) {
    return (a.x - b.x) * (a.x - b.x) + (a.y - b.y) * (a.y - b.y);
}

class UnionFind {
    int N;
    int[] table;
    int[][] groups;

    this(int n) {
        N = n;
        table = new int[](N);
        fill(table, -1);
        groups = new int[][](N);
        foreach (i; 0..N) groups[i] = [i];
    }

    int find(int x) {
        return table[x] < 0 ? x : (table[x] = find(table[x]));
    }

    void unite(int x, int y) {
        x = find(x);
        y = find(y);
        if (x == y) return;
        if (table[x] > table[y]) swap(x, y);
        table[x] += table[y];
        table[y] = x;
        groups[x] ~= groups[y];
        groups[y] = [];
    }
}

nebukuro09の日記

yukicoder No.96 圏外です。

問題概要

解法

感想

コード (D言語)